Съдържание

# WORKDAY.INTL

Връща датата, изчислена от начална дата и зададен брой работни дни преди или след нея. Изчислението може да включва уикендите и празниците като неработни дни.

### Синтаксис

WORKDAY.INTL(НачалнаДата; Дни[; Уикенд [; Празници]])

НачалнаДата: датата, от която започва изчислението.

Дни е броят на работните дни. Положителна стойност означава резултат след началната дата, а отрицателна – преди началната дата.

Уикенд е незадължителен параметър – число или низ, – който указва кои дни от седмицата се считат за почивни. Числовите стойности обозначават следните почивни дни:

Числата от 1 до 7 обозначават двудневни уикенди, а от 11 до 17 – еднодневни.

Число | Уикенд
--- | ---
1 или пропуснат | Събота и неделя
2 | Неделя и понеделник
3 | Понеделник и вторник
4 | Вторник и сряда
5 | Сряда и четвъртък
6 | Четвъртък и петък
7 | Петък и събота
11 | Само неделя
12 | Само понеделник
13 | Само вторник
14 | Само сряда
15 | Само четвъртък
16 | Само петък
17 | Само събота

Низовете за „Уикенд“ позволяват друг начин за задаване на седмичните почивни дни. Низът трябва да съдържа седем знака: нули (0) за работните дни и единици (1) за почивните. Всеки знак отговаря на един ден, започвайки с понеделник. Допустими са само 1 и 0. "1111111" е невалиден низ и не трябва да се използва. Пример: низът "0000011" задава събота и неделя като почивни дни.

Празници е незадължителен списък с дати, които трябва да се смятат за неработни дни. Той може да бъде зададен в диапазон от клетки.

Ако въведете дата като част от формула, наклонените черти и тиретата, използвани като разделители, се интерпретират като аритметични операции. Затова датите, въведени по такъв начин, не се разпознават като дати и причиняват погрешни изчисления. За да предотвратите тълкуване на датите като части от формули, използвайте функцията DATE, например DATE(1954;7;20), или ограждайте датата в кавички и я изписвайте по стандарта ISO 8601, например "1954-07-20". Избягвайте зависими от локала формати като "07/20/54", защото може да се получи грешка в изчисленията, ако документът бъде зареден при различни настройки за локал.

Еднозначно преобразуване е възможно за дати и часове по стандарта ISO 8601 в разширените им формати с разделители. Ако възникне грешка #VALUE!, изчистете полето Генериране на грешка #VALUE! в LibreOffice - Preferences Инструменти - Настройки - LibreOffice Calc - Формула, бутон Подробности... под „Подробни настройки за изчисляване“, списъчно поле Преобразуване от текст в число.

### Примери

Коя дата се пада 20 работни дни след 13 декември 2016 г.? Въведете началната дата в C3 и броя работни дни в D3.

Параметърът „Уикенд“ (число) може да бъде оставен празен или зададен като 1 за подразбираните почивни дни събота и неделя.

Клетките от F3 до J3 съдържат 5 празнични дати за Коледа и Нова година във формат за дата: 24 декември 2016 г., 25 декември 2016 г., 26 декември 2016 г., 31 декември 2016 г. и 1 януари 2017 г.

=WORKDAY.INTL(C3;D3;;F3:J3) връща 11 януари 2017 г. в клетката на резултата, например D6 (форматирайте клетката като дата).

За да зададете петък и събота като седмични почивни дни, задайте 7 за параметъра „Уикенд“.

=WORKDAY.INTL(C3;D3;7;F3:J3) връща 15 януари 2017 г. със стойност 7 на параметъра „Уикенд“.

За да зададете неделя като единствен седмичен почивен ден, задайте 11 за параметъра „Уикенд“.

=WORKDAY.INTL(C3;D3;11;F3:J3) връща 9 януари 2017 г.

Друг начин да укажете неделя като единствен почивен ден за седмицата е да зададете низа "0000001" за параметъра „Уикенд“.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) връща 9 януари 2017 г.

Функцията може да се използва без двата незадължителни параметъра „Уикенд“ и „Празници“, като те бъдат пропуснати:

=WORKDAY.INTL(C3;D3) дава резултат 10 януари 2017 г.

#### Техническа информация

Тази функция е налична от LibreOffice 4.3.

Тази функция НЕ Е част от стандарта Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Пространството от имена е

COM.MICROSOFT.WORKDAY.INTL

Теми, свързани с показаната

Уикистраница за WORKDAY.INTL

Функции за дати и часове

DATE

DATEDIF

DATEVALUE

DAY

DAYS

DAYS360

DAYSINMONTH

DAYSINYEAR

EASTERSUNDAY

EDATE

EOMONTH

HOUR

ISLEAPYEAR

ISOWEEKNUM

MINUTE

MONTH

MONTHS

NETWORKDAYS

NETWORKDAYS.INTL

NOW

SECOND

TIME

TIMEVALUE

TODAY

WEEKDAY

WEEKNUM

WEEKNUM_EXCEL2003

WEEKNUM_OOO

WEEKS

WEEKSINYEAR

WORKDAY

WORKDAY.INTL

YEAR

YEARFRAC

YEARS